# Replicate Table II in Mankiw, Romer and Weil, QJE 1992
open mrw.gdt
genr lny = log(gdp85)
genr ngd = 0.05 + (popgrow/100.0)
genr lngd = log(ngd)
genr linv = log(inv/100.0)
genr lns = log(zeromiss(school)/100.0)
genr x1 = linv - lngd
genr x2 = lns - lngd
# set sample to non-oil producing countries
smpl nonoil --dummy
m1 <- ols lny const linv lngd lns
modeltab add
# restrict 
# b1 + b2 + b3 = 0
# end restrict
genr SSU1 = $ess
genr df1 = $df
ols lny const x1 x2
genr SSR1 = $ess
# set sample to the "better data" countries
smpl intermed --dummy --replace
m2 <- ols lny const linv lngd lns
modeltab add
genr SSU2 = $ess
genr df2 = $df
ols lny const x1 x2
genr SSR2 = $ess
# set sample to the OECD countries
smpl OECD --dummy --replace
m3 <- ols lny const linv lngd lns
modeltab add
genr SSU3 = $ess
genr df3 = $df
ols lny const x1 x2
genr SSR3 = $ess

genr F1 = ((SSR1 - SSU1) / 1) / (SSU1 / df1)
pvalue F 1 df1 F1
genr F2 = ((SSR2 - SSU2) / 1) / (SSU2 / df2)
pvalue F 1 df2 F2
genr F3 = ((SSR3 - SSU3) / 1) / (SSU3 / df3)
pvalue F 1 df3 F3

modeltab show